Creating a Simple Server - No HTTPD Required

Right.

The problem is, we didn't want to install an entire httpd like nginx, or lighttpd, and likewise a Catalyst application for this type of thing would be somewhat overcomplicated, as there was really only be one action to be done.

So what's our solution? We need a simple, light, and forkable http server that can take our requests and process them so.

Enter HTTP::Server::Simple. This is a lightweight, Perl based server module that will allow you to subclass any number of its "flavors" to suit your needs. It comes with the option to prefork, that is, start $x number of instances to fit your traffic load, use CGI like parameters and response/request handling, as well as easy url dispatching (set up a hash of your url->method mapping, pass that to the handler method, done).

You also have the option of writing hooks into various aspects, for instance accept_hook allows you to do something along these lines to allow for SSL encryption:

 sub accept_hook {
        my $self = shift;
        my $fh   = $self->stdio_handle;

        $self->SUPER::accept_hook(@_);

        my $newfh =
        IO::Socket::SSL->start_SSL( $fh, 
            SSL_server    => 1,
            SSL_use_cert  => 1,
            SSL_cert_file => 'myserver.crt',
            SSL_key_file  => 'myserver.key',
        )
        or warn "problem setting up SSL socket: " . IO::Socket::SSL::errstr();

        $self->stdio_handle($newfh) if $newfh;
    }

That's pretty cool. Here's a basic set up that allows you to dispatch to a single and simple method (from the docs):

#!/usr/bin/perl
 {
 package MyWebServer;

 use HTTP::Server::Simple::CGI;
 use base qw(HTTP::Server::Simple::CGI);

 my %dispatch = (
     '/hello' => \&resp_hello,
     # ...
 );

 sub handle_request {
     my $self = shift;
     my $cgi  = shift;

     my $path = $cgi->path_info();
     my $handler = $dispatch{$path};

     if (ref($handler) eq "CODE") {
         print "HTTP/1.0 200 OK\r\n";
         $handler->($cgi);

     } else {
         print "HTTP/1.0 404 Not found\r\n";
         print $cgi->header,
               $cgi->start_html('Not found'),
               $cgi->h1('Not found'),
               $cgi->end_html;
     }
 }

 sub resp_hello {
     my $cgi  = shift;   # CGI.pm object
     return if !ref $cgi;

     my $who = $cgi->param('name');

     print $cgi->header,
           $cgi->start_html("Hello"),
           $cgi->h1("Hello $who!"),
           $cgi->end_html;
 }

 } 

 # start the server on port 8080
 my $pid = MyWebServer->new(8080)->background();
 print "Use 'kill $pid' to stop server.\n";

Really really simple. This is a really neat tool that allows you to add a great deal of flexibility in a pinch.

Next time I'll show you a more complete request processor built with HTTP::Server::Simple... stay tuned.